summaryrefslogtreecommitdiff
path: root/lib/libc/arch/ns32k/sys/__clone.S
blob: d4c48e9bea72d5951d5c9b75016f92a8b648742c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
/*	$NetBSD: __clone.S,v 1.2 2003/11/13 06:29:39 simonb Exp $	*/

/*-
 * Copyright (c) 2001 The NetBSD Foundation, Inc.
 * All rights reserved.
 *
 * This code is derived from software contributed to The NetBSD Foundation
 * by Steve C. Woodford.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 * 3. All advertising materials mentioning features or use of this software
 *    must display the following acknowledgement:
 *	This product includes software developed by the NetBSD
 *	Foundation, Inc. and its contributors.
 * 4. Neither the name of The NetBSD Foundation nor the names of its
 *    contributors may be used to endorse or promote products derived
 *    from this software without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
 * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
 * POSSIBILITY OF SUCH DAMAGE.
 */

#include <sys/errno.h>

#include "SYS.h"

#ifdef WEAK_ALIAS
WEAK_ALIAS(clone,__clone)
#endif

/*
 * int __clone(int (*fn)(void *), void *stack, int flags, void *arg);
 */
ENTRY(__clone)
	movd	S_ARG0,r2
	cmpqd	0,r2		/* NULL function pointer? */
	beq	2f		/* Yup, bomb out */
	movd	S_ARG1,r0
	cmpqd	0,r0		/* NULL stack? */
	beq	2f		/* Yup, bomb out */
	movd	S_ARG3,-4(r0)	/* "Push" clone's `arg' on its new stack */
	addr	-16(r0),tos	/* Syscall arg: stack */
				/*		(-16 because of faked syscall */
				/*		 args and the "push") */
	movd	S_ARG3,tos	/* Syscall arg: flags */
	movqd	0,tos		/* Fake return address */
	SYSTRAP(__clone)	/* Note: `fn' in r2 is preserved */
	adjspd	-12		/* Zap syscall args */
	bcs	_ASM_LABEL(cerror)/* Punt if syscall failed */
	cmpqd	0,r0
	bne	1f		/* We're the parent, just return. */
	lprd	fp,0		/* Clear framepointer */
	jsr	0(r2)		/* We're the clone, call the function */
	movd	r0,tos		/* If clone returns, invoke _exit(3) */
	bsr	_C_LABEL(_exit)
	/* NOTREACHED */

1:	ret	0
2:	movd	EINVAL,r0
	br	_ASM_LABEL(cerror)