summaryrefslogtreecommitdiff
path: root/sys/arch/acorn32/stand/module.ldscript
blob: 406ba4a1f53534c9ea03021439f11be36271e688 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
/* $NetBSD: module.ldscript,v 1.2 2018/12/29 00:35:21 christos Exp $ */

/* linker script for generating RISC OS relocatable modules */
/*
 * The important thing here is that we need the text segment to be at the
 * start so that the module header ends up in the right place when we
 * flatten this into a binary file.  We also don't bother page-aligning
 * anything, because RISC OS won't.
 */

OUTPUT_ARCH(arm)

PHDRS
{
  text PT_LOAD;
  headers PT_PHDR FILEHDR PHDRS;
}

SECTIONS
{
  .text		: { *(.text) *(.gnu.warning) } :text
  _etext = .;
  PROVIDE (etext = .);
  .rodata	: { *(.rodata) }
  .data		: { *(.data) }
  _edata = .;
  PROVIDE (edata = .);
  __bss_start = .;
  .sbss		: { *(.sbss) *(.scommon) }
  .bss		: { *(.bss) *(COMMON) }
  _end = .;
  PROVIDE (end = .);
}