summaryrefslogtreecommitdiff
path: root/sys/arch/mips/conf/stand.ldscript
blob: 73c3730492a21f79f5e80a13489d196f97fe01b4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
/* $NetBSD: stand.ldscript,v 1.8 2021/04/23 08:42:25 simonb Exp $ */

/*  ldscript for NetBSD/mips stand-alone programs */
OUTPUT_ARCH(mips)
ENTRY(_start)
SECTIONS
{
  /*  Read-only sections, merged into text segment.  Assumes the
      stand Makefile sets the start address via -Ttext.  */
  .text      :
  {
    _ftext = . ;
    *(.text)
    *(.text.*)
    *(.gnu.warning)
  } =0
  _etext = .;
  PROVIDE (etext = .);
  .rodata    : { *(.rodata) *(.rodata.*) }
  .data    :
  {
    _fdata = . ;
    *(.data)
    CONSTRUCTORS
  }
  _gp = ALIGN(16);
  .lit8 : { *(.lit8) }
  .lit4 : { *(.lit4) }
  .sdata     : { *(.sdata) }
  _edata  =  .;
  PROVIDE (edata = .);
  __bss_start = .;
  _fbss = .;
  .sbss      : { *(.sbss) *(.scommon) }
  .bss       :
  {
    *(.bss)
    *(COMMON)
  }
  _end = . ;
  PROVIDE (end = .);
  /DISCARD/ : {
    *(.eh_frame_hdr)
    *(.eh_frame)
  }
}